[RESOLU] Déroulement séquentiel automate FESTO

Partie du forum pour tout ce qui concerne les automates industriels B&R, Beckhoff, Phoenix Contact etc...
steph68
Codeur fou
Codeur fou
Messages : 268
Inscription : 21 oct. 2015, 08:23

Re: Déroulement séquentiel automate FESTO

Message par steph68 »

hello,
Alors on ne connait pas quelle est la portée du THEN
l'indentation devrait te mettre sur la bonne piste :mrgreen:

IF / THEN / OTHRW, c'est limpide

@+
Avatar de l’utilisateur
itasoft
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 7035
Inscription : 20 oct. 2015, 10:15
Localisation : Lyon
Contact :

Re: Déroulement séquentiel automate FESTO

Message par itasoft »

slts,
ça doit pas être une indentation agressive car ça ne me saute pas à la figure.
Automaticien privé (de tout)
itasoft@free.fr
philou77
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 2076
Inscription : 21 oct. 2015, 10:00
Localisation : Ile de France

Re: Déroulement séquentiel automate FESTO

Message par philou77 »

Salut,

Je confirme :
pas de end_if.

Le then prend tout ce qu'il y a derrière jusqu'au OTHRW (optionnel)..
Donc cela fait SI ... alors.. OU

la structure if then est valable pour le step !
Chaque step doit au minimum avoir un then (même sans if, je sais c'est con, mais c'est comme cela)

Le passage au step suivant ne sera possible QUE si le THEN du STEP précédent à été réalisé !!

C'est du graphe (ou plutôt du pseudo graphe). il ne colle pas au règles du grafcet pur et dur.
Mais je comprends toujours pas comment je peux aller en étape 40 depuis l'étape 30 alors que l'on teste les mêmes conditions c'est à dire N T80.
tu n'as pas mis tout ton graphe.. il manque le step 80 !!
Si vous avez compris tout ce que je viens d'écrire, c'est que j'ai dû faire une erreur quelque part ! :D
Avatar de l’utilisateur
geronimo
Forcené des structures
Forcené des structures
Messages : 169
Inscription : 20 oct. 2015, 08:46

Re: Déroulement séquentiel automate FESTO

Message par geronimo »

@Philou77

J'ai mis mon graphe en entier dans une réponse dans la page précédente.
Je te le reposte ci joint

Code : Tout sélectionner

STEP 10
 THEN  SET            O1.3           
       LOAD           V200           
         TO           TP80            
       SET            T80             'TIMER 80

STEP 20
 IF                   I5.3           
       AND     N      I5.6           
       AND     N      T80             'TIMER 80
 THEN  SET            O1.0           
       SET            O13.6          
       SET            O14.0          
       SET            C8             
       LOAD           R80            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       
STEP 30
 IF            N      T80             'TIMER 80
 THEN  SET            O17.2          
       LOAD           R81            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 70

STEP 40
 IF            N      I5.6           
       AND     N      T80             'TIMER 80
 THEN  RESET          O14.0          
       LOAD           R82            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 50

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 50
 IF            N      I5.6           
       AND     N      T80             'TIMER 80
 THEN  SET            O14.0          
       INC            CW8            
       LOAD           R83            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 60

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 60
 IF                   CW8            
         =            R84            
 THEN  SET            C8             
       JMP TO 70
 OTHRW JMP TO 40

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 70
 IF            N      I5.6           
       AND     N      T80             'TIMER 80
 THEN  SET            O13.2          
       LOAD           R82            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 80

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 80
 IF            N      I5.6           
       AND     N      T80             'TIMER 80
 THEN  RESET          O13.2          
       INC            CW8            
       LOAD           R83            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 90

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 90
 IF                   CW8            
         =            R84            
 THEN  SET            C8             
       JMP TO 30
 OTHRW JMP TO 70

 IF                   I0.0           
       OR      N      I5.3           
 THEN  JMP TO 100

STEP 100
 IF                   I0.0           
       OR      N      I5.3           
 THEN  RESET          O1.0           
       RESET          O1.3           
       RESET          O13.2          
       RESET          O17.2         

STEP 110
 IF                   I2.5           
 THEN  SET            O13.4          
       SET            O13.6          
       SET            O14.0          
       LOAD           V1000          "10 SECONDS
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80

STEP 120
 IF            N      T80             'TIMER 80
 THEN  RESET          O13.4          
       LOAD           V100           "1 SECOND
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80

STEP 130
 IF            N      T80             'TIMER 80
 THEN  RESET          O13.6          
       RESET          O14.0          
       LOAD           V100           "1 SECOND
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80

STEP 140
 IF            N      F15.2          
       AND     N      T80             
 THEN  RESET          O10.2          
       LOAD           V200           "2 SECONDS
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 155

 IF                   F15.2          
       AND     N      T80             'TIMER 80
 THEN  RESET          O10.2          
       LOAD           V200           "2 SECONDS
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80
       JMP TO 150

STEP 150
 IF            N      T80             'TIMER 80
 THEN  SET            O13.4          
       LOAD           R85            
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80

STEP 155
 IF            N      T80             'TIMER 80
 THEN  RESET          O13.4          
       RESET          O17.4          
       LOAD           V200           "2 SECONDS
         TO           TP80            'TIMER PRESET 80
       SET            T80             'TIMER 80

STEP 160
 IF            N      T80             'TIMER 80
 THEN  RESET          P80             'PROGRAM 80


philou77
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 2076
Inscription : 21 oct. 2015, 10:00
Localisation : Ile de France

Re: Déroulement séquentiel automate FESTO

Message par philou77 »

RE !

Apparemment, ton programme ne passe plus par STEP 40,50 et 60 !
Vu que tu as un saut (JMP) dans le STEP 30 quand tu fais le THEN de celui, impossible de passer à STEP 40 !
Il manquerais un OTHRW au THEN de STEP 30 ou bien un autre IF THEN pour passer à 40 !

pour info, il n'y a pas de STEP en parrallèles dans FST (PAS DEUX STEPS ACTIFS EN MEME TEMPS) ... donc ton grafcet est forcément linéaire !!
si ce besoin est nécessaire, il faut faire un programme pour chaque branche de grafcet !

tu peux avoir la doc fst ici : https://www.festo.com/net/SupportPortal ... th_FST.pdf

structure normale
IF
THEN
(OTHRW)

structure simple sans conditions
THEN

structure avec 2 conditions ou plus
seul le dernier IF lu permet de passer au step suivant, souvent tu auras un JMP dans les autres conditions
Cela permet d'échapper une boucle dans le grafcet avec le dernier IF
IF
THEN
(OTHRW)

IF
THEN

par exemple en STEP 90:
boucle entre 90-30 (si CW8 = R84) sinon boucle entre 90-70
Sortie en STEP 100 si I0.0 ou /I5.3 (conditions que tu retrouve aussi en STEP 70 ou STEP 80)


en espérant t'avoir aidé un peu
Dernière modification par philou77 le 13 juil. 2016, 23:39, modifié 1 fois.
Si vous avez compris tout ce que je viens d'écrire, c'est que j'ai dû faire une erreur quelque part ! :D
Avatar de l’utilisateur
itasoft
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 7035
Inscription : 20 oct. 2015, 10:15
Localisation : Lyon
Contact :

Re: Déroulement séquentiel automate FESTO

Message par itasoft »

slts,
On ne se comprends pas. Qu'il y ai un end_if ou pas ça m'est égal, je veux juste savoir ou serait le END_IF si il y an avait un
Automaticien privé (de tout)
itasoft@free.fr
philou77
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 2076
Inscription : 21 oct. 2015, 10:00
Localisation : Ile de France

Re: Déroulement séquentiel automate FESTO

Message par philou77 »

Salut Itasoft..

Je te répondais pas..pardon

Mais non il n'y a pas de end_if ;)
le end_if serait en fait le IF suivant dans le même STEP ou bien le STEP suivant
Regarde le lien donné plus haut à partir de la page 90..
Si vous avez compris tout ce que je viens d'écrire, c'est que j'ai dû faire une erreur quelque part ! :D
Avatar de l’utilisateur
itasoft
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 7035
Inscription : 20 oct. 2015, 10:15
Localisation : Lyon
Contact :

Re: Déroulement séquentiel automate FESTO

Message par itasoft »

ok,
Donc la portée du IF/THEN c'est : La ligne du THEN + Toutes les lignes suivantes jusqu'au prochain IF ou au prochain THEN ou à la fin de l'étape.
c'est bien ça ?????
Automaticien privé (de tout)
itasoft@free.fr
Avatar de l’utilisateur
geronimo
Forcené des structures
Forcené des structures
Messages : 169
Inscription : 20 oct. 2015, 08:46

Re: Déroulement séquentiel automate FESTO

Message par geronimo »

Merci beaucoup Pilou77 pour ton aide.
philou77
Mi homme - Mi automate
Mi homme - Mi automate
Messages : 2076
Inscription : 21 oct. 2015, 10:00
Localisation : Ile de France

Re: Déroulement séquentiel automate FESTO

Message par philou77 »

Salut !

De rien.

Oui Itasoft, t'as bien compris..
il faut aussi rajouter OTHRW ( qui est en fait l'évaluation FAUSSE du IF !)

C'est du FESTO, c'est de l'allemand...c'est pas simple..et c'est PAS du grafcet !!

Personnellement, je ne suis pas fan et n'ai jamais utilisé les steps...je fait tout en ladder avec des mémoires ..c'est bien plus simple...
Si vous avez compris tout ce que je viens d'écrire, c'est que j'ai dû faire une erreur quelque part ! :D
Répondre