Nombre de variables utlisées Unity

[Schul]

Bonjour à tous !

Pour un projet de modernisation de supervision, j'ai besoin de remplacer une vieille supervision panorama sur fipway par Pc Vue sur Ethernet.
Bref, pour dimensionner au mieux la licence Pc VUe, j'aurais besoin de connaitre le nombre de variables utilisées dans le programme du TSX programmé en Unity. J'aurais pu exporter la liste des variables et avec Excel compter assez facilement, cependant j'ai plein de %M et %MW utilisés tels quels sans symboles, donc non répertoriés dans les variables.Je retourne un peu le soft depuis hier et je n'ai pas trouvé de bonnes choses sur notre ami google, du coup je voulais savoir si il y avait une méthode et savoir comment vous faisiez ??

Merci d'avance.

[itasoft]

slts,
moi je fais ça avec une moulinette en VBA, la demander si besoin

[Schul]

t'as combien de moulinettes Itasoft ?? Ben j'avoue que si il n'existe pas de solution "dédiée", je suis preneur...

[itasoft]

slts,
Copier et coller la Sub dans le VBA de Excel


Sub CompteurMMWInXef()
Dim TXT As String, fileNameSource As String
Dim mySize As Long, nbM As Long, nbMW As Long
Dim number1 As Integer, number2 As Integer
Dim oRegExp As Object, oMatches As Object, oMatch As Object

'======= Mettre ici le Chemin et nom du fichier .XEF (en Majuscules) =========
fileNameSource = "D:\AFF\PROJET.XEF"
'=============================================================================
If InStr(fileNameSource, ".XEF") = 0 Then Exit Sub

'Objet Régular-expressions
Set oRegExp = CreateObject("VBScript.RegExp")
oRegExp.Global = True
oRegExp.IgnoreCase = True

'Charge fichier .XEF
mySize = FileLen(fileNameSource)
TXT = String(mySize, Chr(0))
number1 = FreeFile
Open fileNameSource For Binary As #number1
Get #number1, , TXT
Close #number1

oRegExp.Pattern = "%M[0-9]+"
Set oMatches = oRegExp.Execute(TXT)
nbM = oMatches.Count

oRegExp.Pattern = "%MW[0-9]+"
Set oMatches = oRegExp.Execute(TXT)
nbMW = oMatches.Count

'résultat
MsgBox ("Nombre de %M=" & nbM)
MsgBox ("Nombre de %MW=" & nbMW)


End Sub

[Schul]

Super Itasoft! Je te remercie ça marche nikel!

Petite question si par exemple j'ai :
%Mw0=%MW0+1
if %MW0=2 enfin bref il me sort du coup 3 %MW alors que c'est 3 fois le même.

Tu as déja fait une moulinette bis qui te comptait les %MW différents ?

[itasoft]

oui à condition que ya en a pas trop
combien ça te trouve de %M et de %MW

[Schul]

%M : 814
%MW : 2507

[itasoft]

slts, c'est bon ça passe

Sub CompteurMMWInXef_BIS()
Dim TXT As String, MString As String, MWString As String, sOBJ As String, sSS As String, fileNameSource As String
Dim mySize As Long, nbM As Long, nbMW As Long
Dim number1 As Integer, number2 As Integer
Dim oRegExp As Object, oMatches As Object, oMatch As Object

'======= Mettre ici le Chemin et nom du fichier .XEF (en Majuscules) =========
fileNameSource = "D:\AFF\PROJET.XEF"
'=============================================================================

If InStr(fileNameSource, ".XEF") = 0 Then Exit Sub

'Objet Régular-expressions
Set oRegExp = CreateObject("VBScript.RegExp")
oRegExp.Global = True
oRegExp.IgnoreCase = True

'Charge fichier .XEF
mySize = FileLen(fileNameSource)
TXT = String(mySize, Chr(0))
number1 = FreeFile
Open fileNameSource For Binary As #number1
Get #number1, , TXT
Close #number1

oRegExp.Pattern = "%M[0-9]+"
Set oMatches = oRegExp.Execute(TXT)
For Each oMatch In oMatches
sOBJ = Replace(oMatch.Value, "%M", "M")
sSS = "/" & sOBJ & "/"
If InStr(MString, sSS) = 0 Then
MString = MString & sOBJ & "/"
nbM = nbM + 1
End If
Next oMatch

oRegExp.Pattern = "%MW[0-9]+"
Set oMatches = oRegExp.Execute(TXT)
For Each oMatch In oMatches
sOBJ = Replace(oMatch.Value, "%MW", "W")
sSS = "/" & sOBJ & "/"
If InStr(MWString, sSS) = 0 Then
MWString = MWString & sOBJ & "/"
nbMW = nbMW + 1
End If
Next oMatch


'resultat
MsgBox ("Nombre de %M differents =" & nbM)
MsgBox ("Nombre de %MW differents =" & nbMW)

End Sub

[Schul]

Parfait !

Je passe à 205 %MW, j'ai un peu surdimensionné ma clé de 2000 variables du coup :/

Encore merci pour ce coup de main très rapide et très efficace !

[Bernardo59]

Salut Schul,

Ce n'est pas parce que tu as 2000 variables dans le programme que la supervision va tous les récupérer.
Il faudrait plus te pencher sur la supervision Panorama pour connaitre le nombre de variable qu'elle va récupérer dans l'automate, à savoir dans: "Base de données\Réseau\"Nom de l'automate"\

A+